옷갈아입히기 시스템 만들기

Long Live The Queen 을 설명하다가 이런 시스템을 블로그에서 다뤄본적이 없는 듯하여 작성해봅니다.

ConditionSwitch와 im.Composite 함수를 활용해 간단히 만들어본 시스템입니다.

init python:
    cloth = None # 현재 입고 있는 옷 변수

init -1:
    # 하트옷 이미지
    image zola heart = im.Composite(
                            (198, 388), # 합성할 결과물 이미지 크기
                            (0, 0), "person.png", # 합성할 이미지를 배치할 위치. 왼쪽위 꼭지점의 x, y 좌표, 합성할 이미지 파일 이름
                            (0, 0), "heart.png") # 하트 옷
    # 별옷 이미지                        
    image zola star = im.Composite(
                            (198, 388), # 합성할 결과물 이미지 크기
                            (0, 0), "person.png", # 합성할 이미지를 배치할 위치. 왼쪽위 꼭지점의 x, y 좌표, 합성할 이미지 파일 이름
                            (0, 0), "star.png") #별 옷
                            
init:
    image zola = ConditionSwitch(
                            "cloth==None", "person.png", # 안 입으면 옷 없음
                            "cloth=='star'", "zola star", # 별 선택하면 별옷 이미지 표시
                            "cloth=='heart'", "zola heart") # 하트 선택하면 하트옷 이미지 표시
    
label start:
    show zola
    "뿌잉뿌잉"
    
    menu:
        "옷을 입어볼까?"
        "별옷":
            $ cloth = "star"
            
        "하트옷":
            $ cloth = "heart"
            
        "옷 안 입음":
            $ cloth = None
        
    show zola
    '얍'

간단하게 만든다고 선택지로 해봤는데, 스크린 언어의 이미지 버튼을 활용해서 만든다면 뭔가 옷 아이콘을 클릭했을 때 변경된다던가 하는 좀 그럴싸한 외형을 갖출 수 있을 겁니다.

아니면 부위별로(악세사리, 하의, 눈, 얼굴 ...) 변수를 나눠서 캐릭 이미지를 합성하게 된다면 좀 더 세부적인 변경도 가능하도록 만들 수 있겠죠.